Kód:
@echo off
::*************************************************************************************************************
:: XDCAM 422,50Mbits from VEGAS generated MXF into MKV to be able to play it in media players like WDTV Live, *
:: no recompression is done, just re-wrapping mxf video and two audio channels into MKV container. *
:: *
:: Drag and drop MXF files onto BAT file *
:: *
:: command lines: *
:: ffmpeg -i video.mxf -c:v copy -an -sn video.m2v *
:: ffmpeg -i video.mxf -map 0:1 -map 0:2 -c:a:0 pcm_s16le -c:a:1 pcm_s16le -filter_complex amerge audio.wav *
:: mkvmerge -o video.mkv video.m2v audio.wav *
::*************************************************************************************************************
SET ffmpeg="%~dp0tools\ffmpeg.exe"
SET mkvmerge="%~dp0tools\mkvmerge.exe"
SET temp_dir=%~dp0temp
SET destination=%~dp0mkv
if not exist "%temp_dir%" MD "%temp_dir%"
if not exist "%destination%" MD "%destination%"
SET root=%~dp0
set i=0
CD /D %root%
:loop
if "%~d1%~p1%~n1%~x1"=="" goto konec
if "%~x1"=="" echo vynechavam %~n1 adresar & echo --------------------------------------------- & shift & goto loop
if /i %~x1 NEQ .mxf echo vynechavam %~n1%~x1 , neni to mxf & echo --------------------------------------------- & shift & goto loop
%ffmpeg% -y -i "%~d1%~p1%~n1.mxf" -c:v copy -an -sn "%temp_dir%\video.m2v"
%ffmpeg% -y -i "%~d1%~p1%~n1.mxf" -map 0:1 -map 0:2 -c:a:0 pcm_s16le -c:a:1 pcm_s16le -filter_complex amerge "%temp_dir%\audio.wav"
%mkvmerge% -o "%destination%\%~n1.mkv" "%temp_dir%\video.m2v" "%temp_dir%\audio.wav"
set /a i=%i% + 1
shift
echo ---------------------------------------------
goto loop
:konec
echo.
if %i%==0 echo Zadny MKV nebyl vytvoren & echo. & pause & exit
echo Pocet vytvorenych MKV=%i%
echo MKV doubory jsou ve slozce: %destination%
echo.
pause